Generics: What's a "CONSTRUCTOR constraint"?

Asked 2008-12-20T20:17:07.523

I made a custom TObjectList descendant designed to hold subclasses of a base object class. It looks something like this:

interface
   TMyDataList<T: TBaseDatafile> = class(TObjectList<TBaseDatafile>)
   public
      constructor Create;
      procedure upload(db: TDataSet);
   end;

implementation

constructor TMyDataList<T>.Create;
begin
   inherited Create(true);
   self.Add(T.Create);
end;

I want each new list to start out with one blank object in it. It's pretty simple, right? But the compiler doesn't like it. It says:

"Can't create new instance without CONSTRUCTOR constraint in type parameter declaration" I can only assume this is something generics-related. Anyone have any idea what's going on and how I can make this constructor work?

Edit Report

2 Answers

You're trying to create an instance of T via T.Create. This doesn't work because the compiler doesn't know that your generic type has a parameterless constructor (remember: this is no requirement). To rectify this, you've got to create a constructor constraint, which looks like this:

<T: constructor>

or, in your specific case:

<T: TBaseDatafile, constructor>

answered 2008-12-20T20:23:31.897

Just a quick update to an old question..

You don't need the constructor constraint and can also do this on object's with parameters by using RTTI like this (using RTTI or System.RTTI with XE2)

constructor TMyDataList<T>.Create;
var
  ctx: TRttiContext;
begin
   inherited Create(true);
   self.Add(
     ctx.
     GetType(TClass(T)).
     GetMethod('create').
     Invoke(TClass(T),[]).AsType<T>
   );
end;

If you have parameters, just add them like this

constructor TMyDataList<T>.Create;
var
  ctx: TRttiContext;
begin
   inherited Create(true);
   self.Add(
     ctx.
     GetType(TClass(T)).
     GetMethod('create').
     Invoke(TClass(T),[TValue.From('Test'),TValue.From(42)]).AsType<T>
   );
end;

answered 2011-09-04T20:04:55.423

Generics: What's a "CONSTRUCTOR constraint"?

2 Answers

Your Answer